Eliminar vocales en una lista

Escriba un progtwig que elimine vocales ( String , NoVowelsString ) que elimine todas las vocales de una cadena dada.

Hasta ahora tengo la vowel(X):- member(X,[a,e,i,o,u]) la condición vowel(X):- member(X,[a,e,i,o,u]) . Luego pensé en el que borra todos los elementos de la otra lista:

 delete2([],L1,L1). delete2([H|T],L1,L3) :- delete2(H,L1,R2), delete2(T,R2,L3). 

Así que al tener estos dos pensé que podría poner una condición a los elementos que se eliminan que tienen que ser miembro de [a,e,i,o,u] . Aunque todavía no he llegado a ninguna parte.

Aquí está el código

 deleteV([H|T],R):-member(H,[a,e,i,o,u]),deleteV(T,R),!. deleteV([H|T],[H|R]):-deleteV(T,R),!. deleteV([],[]). 

¿Que hace? Primero se pregunta a sí mismo? Es la cabeza una vocal Sí-> Lo ignoramos. No-> Lo necesitamos. Si encuentra una lista vacía, construye la lista de resultados, y al regresar de retroceder, agrega los consignatos al frente. Este código fue probado en SWIProlog.

Lo siguiente se basa en la reificación del término igualdad / desigualdad .

Primero, primero definimos list_memberd_t/3 , que se comporta como memberd_truth/3 pero tiene un orden de argumento diferente:

 list_memberd_t([] ,_,false). list_memberd_t([Y|Ys],X,Truth) :- if_(X=Y, Truth=true, list_memberd_t(Ys,X,Truth)). list_memberd_truth(Xs,X,Truth) :- list_memberd_t(Xs,X,Truth). 

En aras de la brevedad, definamos memberd_t/3 basado en list_memberd_t/3 :

 memberd_t(X,Xs,Truth) :- list_memberd_t(Xs,X,Truth). 

Como paralelo a la library(apply) , definamos tinclude/3 :

 :- meta_predicate tinclude(2,?,?). tinclude(P_2,Xs,Zs) :- list_tinclude_list(Xs,P_2,Zs). list_tinclude_list([], _P_2,[]). list_tinclude_list([E|Es],P_2,Fs0) :- if_(call(P_2,E), Fs0 = [E|Fs], Fs0 = Fs), list_tinclude_list(Es,P_2,Fs). 

tfilter/3 es otro nombre para tinclude/3 :

 tfilter(P_2,As,Bs) :- tinclude(P_2,As,Bs). 

A continuación, definimos el meta-predicado texclude/3 , lo opuesto a tinclude/3 :

 :- meta_predicate texclude(2,?,?). texclude(P_2,Xs,Zs) :- list_texclude_list(Xs,P_2,Zs). list_texclude_list([],_,[]). list_texclude_list([E|Es],P_2,Fs0) :- if_(call(P_2,E), Fs0 = Fs, Fs0 = [E|Fs]), list_texclude_list(Es,P_2,Fs). 

¡Ahora usemoslos juntos!

 ?- texclude(list_memberd_truth([a,e,i,o,u]), [d,e,l,e,t,e,' ',v,o,w,e,l,s,' ',i,n,' ',a,' ',l,i,s,t], Filtered). Filtered = [d, l, t, ' ',v, w, l,s,' ', n,' ', ' ',l, s,t]. 

Editar

Como alternativa al uso de texclude/3 , usemos tinclude/3 con un predicado auxiliar not/3 para invertir el valor de verdad:

 :- meta_predicate not(2,?,?). not(P_2,X,Truth) :- call(P_2,X,Truth0), truth_flipped(Truth0,Truth). truth_flipped(true,false). truth_flipped(false,true). 

Consulta de muestra:

 ?- tinclude(not(list_memberd_truth([a,e,i,o,u])), [d,e,l,e,t,e,' ',v,o,w,e,l,s,' ',i,n,' ',a,' ',l,i,s,t], Filtered). Filtered = [d, l, t, ' ',v, w, l,s,' ', n,' ', ' ',l, s,t]. 

aquí una solución usando DCG. Observe cómo se obtiene el ‘resultado’ (sin argumentos que pasan, solo listas de diferencias)

 novowels --> ("a";"e";"i";"o";"u"), !, novowels. % or .. % novowels --> [C], {memberchk(C, "aeiou")}, !, novowels. novowels, [C] --> [C], !, novowels. novowels --> []. 

Debo confesar que el segundo corte no me quiere, pero parece necesario.

prueba:

 ?- phrase(novowels, "abcdefghilmnopq", L),format('~s',[L]). bcdfghlmnpq L = [98, 99, 100, 102, 103, 104, 108, 109, 110|...]. 

editar Acerca del segundo corte, parece ser requerido por la notación de ‘mano izquierda’: si codigo con argumento, sin cortar, obtengo un análisis correcto:

 novowels(Cs) --> ("a";"e";"i";"o";"u"), !, novowels(Cs). % novowels(Cs) --> [C], {memberchk(C, "aeiou")}, !, novowels(Cs). novowels([C|Cs]) --> [C], novowels(Cs). novowels([]) --> []. 

prueba:

 ?- phrase(novowels(L), "abcdefghilmnopq"),format('~s',[L]). bcdfghlmnpq L = [98, 99, 100, 102, 103, 104, 108, 109, 110|...] ; false. 

Me pregunto si esto es un error del traductor DCG, o (más probablemente) mi culpa …